10 POKE53280,.:POKE53281,.:PRINT"[147][154]CALCULATING...":GOTO50
20 A$(Y)=A$(Y)+RIGHT$(S$+STR$(D%),6):RETURN
30 FOR Y=S TO F:READ D$:A$(Y)=LEFT$(D$+S$,10):A$(Y)="[154]"+A$(Y)+"[159]"
35 FOR X=0 TO 4:READ D%
40 A%(E,X)=A%(E,X)+D%:GOSUB 20:NEXT:NEXT:RETURN
50 FOR X=1 TO 30:S$=S$+" ":NEXT:FOR X=1 TO 40:L$=L$+"-":NEXT:L$="[154]"+L$
100 W$="[147][159]           WEEK1 WEEK2 WEEK3 WEEK4 WEEK5[154]"
110 I$="NET INCOME"+S$
120 DATA SALARY,300,300,300,300,300
130 DATA OTHER,0,50,0,50,0
140 REM
200 ID=2:E$="   EXPENSE"+S$
210 DATA CHURCH,35,40,35,40,35
220 DATA RENT,0,0,0,575,0
230 DATA FOOD,45,45,45,45,45
240 DATA PHONE,0,25,0,0,0
250 DATA LIGHTS,0,0,50,0,0
260 DATA WATER,20,0,0,0,0
270 DATA TRASH,8,0,0,0,0
280 DATA GASOLINE,10,10,10,10,10
290 DATA CAR LOAN,0,133,0,0,0
300 DATA CAR INS,0,31,0,0,0
310 DATA LIFE INS,13,0,0,0,0
320 DATA BANK CARD,25,0,0,0,0
330 DATA STORE CARD,10,0,0,0,0
340 DATA SAVINGS,10,10,10,10,10
350 REM
400 ED=14:D=ID+ED+10:DIM A$(D),A%(4,5):A$(0)=W$:A$(1)=I$:S=2:F=S+ID-1:E=0
410 GOSUB 30:T=Y:A$(Y+4)=E$:S=Y+5:F=S+ED-1:E=3
415 GOSUB 30:TT=Y:A$(T)="[154] *FORWARD [159]"
420 A$(T+1)=L$:A$(T+2)="[154] TOTAL IN [159]":A$(T+3)=L$:A$(Y)=L$
425 A$(Y+1)="[154] TOTAL EX [159]"
430 A$(Y+2)=L$:A$(Y+3)="[154] *BALANCE [159]"
435 FOR X=0 TO 4:A%(2,X)=A%(0,X)+A%(1,X):Y=T
440 D%=A%(1,X):GOSUB 20:Y=T+2:D%=A%(2,X):GOSUB 20
445 A%(4,X)=A%(2,X)-A%(3,X):Y=TT+1
450 D%=A%(3,X):GOSUB 20:Y=TT+3:D%=A%(4,X):GOSUB 20:A%(1,X+1)=A%(4,X):NEXT
460 FOR X=0 TO D:PRINT A$(X);:IF X>22 GOTO 480
470 NEXT:PRINT:GOTO 500
480 GET K$:IF K$="" GOTO 480
490 GOTO470
500 PRINT"[159]0[154])EXIT [159]1[154])REDISPLAY [159]2[154])SAVE [159]3[154])PRINT[145]"
501 GETA$:IFA$<"0"ORA$>"3"THEN501
502 K=VAL(A$):IFK=.THEN60000
505 ON K GOTO 460,510,520
510 SAVE"BUDGET",8:GOTO500
520 OPEN 4,4:FOR X=0 TO D:PRINT#4,A$(X):NEXT:CLOSE4:GOTO500
60000 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
60010 IFER<>63THENEND
60020 PRINT"[147][144]LOAD"CHR$(34)"HELLO CONNECT"CHR$(34)",8":PRINT"RUN"
60030 POKE631,13:POKE632,13:POKE198,2:END